【AccessVBA/ExcelVBA】テキストファイルの出力～Open/Printステートメント

Open pathname For mode [Access access] [lock] As [#]filenumber [Len=reclength]

Private Sub エクスポート_Click()
    Dim strFile As String
    Dim intFree As Integer
    Dim objRS As Recordset
    Dim strA() As String
    Dim intLoop As Integer
'出力先のファイル名を変数に格納
    strFile = "C:\Users\hogehoge\Desktop\テーブル1.txt"
'使用可能なファイル番号を取得
    intFree = FreeFile
'テキストファイルをOutputモードで開く
    Open strFile For Output As #intFree
'出力したいテーブルをレコードセットで開く
    Set objRS = CurrentDb.OpenRecordset("テーブル1", _
                                        dbOpenForwardOnly, _
                                        dbReadOnly)
'1行目に出力する項目名を配列に格納
    ReDim strA(objRS.Fields.Count - 1)
    For intLoop = 0 To objRS.Fields.Count - 1
        strA(intLoop) = objRS.Fields(intLoop).Name
    Next intLoop
'1行目を出力
    Print #intFree, Join(strA, vbTab)
'2行目以降を出力
    Do Until objRS.EOF
        For intLoop = 0 To objRS.Fields.Count - 1
            Select Case objRS.Fields(intLoop).Type
            Case dbChar, dbMemo, dbText
                '文字列型項目の場合はダブルクォーテーションで囲う
                strA(intLoop) = """" & Nz(objRS.Fields(intLoop), "") & """"
            Case Else
                strA(intLoop) = Nz(objRS.Fields(intLoop), "")
            End Select
        Next intLoop
        Print #intFree, Join(strA, vbTab)
        objRS.MoveNext
    Loop
    objRS.Close
    Close #intFree
    MsgBox "出力完了", vbOKOnly + vbInformation, "サンプルコード"
End Sub